/*****************************************************************/
/*                                                               */
/*  ams7-CI-simulation.jsl is a script that simulates            */
/*    the following process:                                     */
/*                                                               */
/*     Draw a sample of size n using SRS from a population       */
/*       data set with N rows called Y (stored in the current    */
/*       data table), and compute the lower and upper limits     */
/*       of the 95% confidence interval for the mean based on    */
/*       the t machinery;                                        */
/*     repeat this process M times and store these M lower       */ 
/*       and upper limits in columns called Left and Right       */
/*       in a data table called Results.                         */
/*                                                               */
/*****************************************************************/

// Reference data table;

dt=current data table();

dt<<ClearRowStates;

// Specify sample size

n=5; // size of sample drawn from population;

// Specify the number of samples;

M=500; // number of replications of simulation experiment;

// Preparing a new data table for the results to be stored;

ResultsDT=NewTable("Results.jmp",
                     NewColumn("Left"),
                     NewColumn("Right")
                   );

For(i=1,i<=M,i++,
     currentdatatable(dt);
     eval(substitute(expr(current data table()<<SelectRandomly(ss)), 
       expr(ss), n));
     dt<<Invert Row Selection;
     dt<<Hide;
     dt<<Exclude;
     Dist=Distribution(Continuous Distribution(Column(:Y)));
     RDist=Dist<<report;
     stats=RDist["Moments"][NumberColBox(1)]<<get as matrix;
     ResultsDT<<AddRow(1);
       Column(ResultsDT,1)[row()] = stats[5,1]; // lower limit of CI
       Column(ResultsDT,2)[row()] = stats[4,1]; // upper limit of CI;
     Dist<<Close Window;
     dt<<ClearRowStates;
   );